**Programski kod delta robota DR-3*i*B**

**/PROG RSR0001**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 0;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1: ;

2: CALL MAIN\_PROGRAM\_DR3 ;

3: ;

/POS

/END

//

**/PROG MAIN\_PROGRAM\_DR3**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 0;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1: ;

2: RUN FENCE\_OPEN ;

3: RUN CONV\_TEST\_2 ;

4: CALL MAIN\_TRACKING ;

5: ;

/POS

/END

//

**/PROG FENCE\_OPEN**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 0;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1: LBL[1] ;

2: IF DI[16:Fence Open M3 Side]=ON,JMP LBL[2] ;

3: JMP LBL[1] ;

4: ;

5: LBL[2] ;

6: UALM[10] ;

7: ;

/POS

/END

//

**/PROG CONV\_TEST\_2**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 0;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1: LBL[25] ;

2:L P[1] 1300mm/sec CNT100 INC ;

3: JMP LBL[25] ;

4: ;

/POS

P[1]{

GP2:

UF : 0, UT : 1,

J1= -200.000 deg

};

/END

//

**/PROG MAIN\_TRACKING**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 0;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : FALSE;

/MN

1: UFRAME\_NUM=0 ;

2: UTOOL\_NUM=0 ;

3: OVERRIDE=90% ;

4: ;

5: DO[11:CameraLight\_Status]=ON ;

6: ;

7: LBL[1] ;

8: CALL MAIN\_CLEARPOSREG ;

9: R[51:LineCount\_ENC1]=0 ;

10: R[54]=0 ;

11: R[55:Counter\_Camera]=0 ;

12: R[52:Counter\_ENC1]=60 ;

13: R[56:Offset\_Counter]=30 ;

14: ;

15: LBL[2] ;

16: R[R[52]]=0 ;

17: R[52:Counter\_ENC1]=R[52:Counter\_ENC1]+1 ;

18: IF R[52:Counter\_ENC1]<=70,JMP LBL[2] ;

19: ;

20: R[52:Counter\_ENC1]=60 ;

21: R[53:Object\_Trigger]=60 ;

22: ;

23: LINE[2] ON ;

24: ;

25: RUN MAIN\_SUBPRG ;

26: RUN MAIN\_VISPRG ;

27: ;

28: LBL[10] ;

29: ;

30:J PR[20:Home\_Position] 20% FINE ;

31: ;

32: WAIT R[R[53]]<>0 ;

33: ;

34: SETTRIG LNSCH[1] R[R[53]] ;

35: SELBOUND LNSCH[1] BOUND[1] ;

36: ;

37: CALL MAIN\_VIS\_PICK ;

38: ;

39:L PR[20:Home\_Position] 800mm/sec CNT100 ;

40: ;

41: CALL MAIN\_PLACE ;

42: ;

43: R[53:Object\_Trigger]=R[53:Object\_Trigger]+1 ;

44: IF R[53:Object\_Trigger]<=70,JMP LBL[15] ;

45: R[53:Object\_Trigger]=60 ;

46: ;

47: LBL[15] ;

48: ;

49: JMP LBL[10] ;

50: ;

/POS

/END

//

**/PROG MAIN\_CLEARPOSREG**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 0;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1: ;

2: PR[23:Vision\_Offset]=PR[25:Frame\_Offset] ;

3: PR[30]=PR[24:Clear\_Position] ;

4: PR[31]=PR[24:Clear\_Position] ;

5: PR[32]=PR[24:Clear\_Position] ;

6: PR[33]=PR[24:Clear\_Position] ;

7: PR[34]=PR[24:Clear\_Position] ;

8: PR[35]=PR[24:Clear\_Position] ;

9: PR[36]=PR[24:Clear\_Position] ;

10: PR[37]=PR[24:Clear\_Position] ;

11: PR[38]=PR[24:Clear\_Position] ;

12: PR[39]=PR[24:Clear\_Position] ;

13: PR[40]=PR[24:Clear\_Position] ;

14: ;

/POS

/END

//

**/PROG MAIN\_SUBPRG**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 0;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1: LBL[20] ;

2: ;

3: R[52:Counter\_ENC1]=60 ;

4: ;

5: LBL[30] ;

6: R[R[52]]=0 ;

7: ;

8: WAIT DI[1:Object\_Presence]=ON+ ;

9: LINECOUNT[2] R[51] ;

10: R[R[52]]=R[51:LineCount\_ENC1] ;

11: R[51:LineCount\_ENC1]=0 ;

12: R[54]=0 ;

13: ;

14: R[52:Counter\_ENC1]=R[52:Counter\_ENC1]+1 ;

15: IF R[52:Counter\_ENC1]>70,JMP LBL[20] ;

16: ;

17: JMP LBL[30] ;

18: ;

/POS

/END

//

**/PROG MAIN\_VISPRG**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 0;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1: LBL[1] ;

2: R[55:Counter\_Camera]=30 ;

3: ;

4: LBL[5] ;

5: LBL[2] ;

6: WAIT DI[2:Camera\_Trigger]=ON+ ;

7: VISION RUN\_FIND 'FINDTHEOBJECT\_210178' ;

8: ;

9: VISION GET\_OFFSET 'FINDTHEOBJECT\_210178' VR[1] JMP LBL[5] ;

10: ;

11: PR[R[55]]=VR[1].FOUND\_POS[1] ;

12: ;

13: R[55:Counter\_Camera]=R[55:Counter\_Camera]+1 ;

14: ;

15: IF R[55:Counter\_Camera]>39,JMP LBL[1] ;

16: ;

17: JMP LBL[2] ;

18: ;

/POS

/END

//

**/PROG MAIN\_VIS\_PICK**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 1;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : FALSE;

/MN

1: ;

2: PR[23,2:Vision\_Offset]=PR[R[56],2] ;

3: ;

4: PR[23,6:Vision\_Offset]=PR[R[56],6] ;

5: ;

6:L P[2] 650mm/sec CNT25 Offset,PR[23:Vision\_Offset] ;

7: ;

8: WAIT .25(sec) ;

9:L P[1] 500mm/sec FINE Offset,PR[23:Vision\_Offset] ;

10: ;

11: WAIT .25(sec) ;

12: DO[2:Vacuum\_Y2]=ON ;

13: WAIT .25(sec) ;

14: ;

15:L P[2] 650mm/sec CNT25 Offset,PR[23:Vision\_Offset] ;

16: ;

17: R[56:Offset\_Counter]=R[56:Offset\_Counter]+1 ;

18: ;

19: IF R[56:Offset\_Counter]<=39,JMP LBL[20] ;

20: ;

21: R[56:Offset\_Counter]=30 ;

22: LBL[20] ;

/POS

P[1]{

GP1:

UF : 0, UT : 0, CONFIG : ', , 0',

X = -472.000 mm, Y = -18.000 mm, Z = 11.000 mm,

W = 180.000 deg, P = 0.000 deg, R = 109.707 deg

};

P[2]{

GP1:

UF : 0, UT : 0, CONFIG : ', , 0',

X = -470.000 mm, Y = -18.000 mm, Z = 35.000 mm,

W = 180.000 deg, P = 0.000 deg, R = 109.707 deg

};

/END

//

**/PROG MAIN\_PLACE**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 0;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1:L PR[21:Place\_Position] 650mm/sec CNT25 Tool\_Offset,PR[22:Z\_Offset\_Place] ;

2: ;

3:L PR[21:Place\_Position] 800mm/sec FINE ;

4: ;

5:L PR[26:Place\_Motion] 90mm/sec FINE DB 15.0mm,DO[2:Vacuum\_Y2]=OFF ;

6: WAIT .25(sec) ;

7: ;

8:L PR[26:Place\_Motion] 800mm/sec CNT25 Tool\_Offset,PR[22:Z\_Offset\_Place] ;

9: ;

/POS

/END

//

**IO STATUS::**

|  |  |
| --- | --- |
| DIN[ 1] OFF Object\_Presence  DIN[ 2] OFF Camera\_Trigger  DIN[ 3] OFF Palette\_Presence  DIN[ 4] OFF Slider\_Presence  DIN[ 5] OFF  DIN[ 6] OFF  DIN[ 7] OFF  DIN[ 8] OFF  DIN[ 9] OFF  DIN[ 10] OFF  DIN[ 11] OFF  DIN[ 12] OFF  DIN[ 13] OFF  DIN[ 14] OFF Restart  DIN[ 15] OFF Start  DIN[ 16] OFF Fence Open M3 Side | DOUT[ 1] OFF Vacuum\_Y1  DOUT[ 2] OFF Vacuum\_Y2  DOUT[ 3] OFF Tool\_Out  DOUT[ 4] OFF Tool\_In  DOUT[ 5] OFF  DOUT[ 6] OFF  DOUT[ 7] OFF  DOUT[ 8] OFF  DOUT[ 9] OFF  DOUT[ 10] OFF  DOUT[ 11] OFF CameraLight\_Status  DOUT[ 12] OFF  DOUT[ 13] OFF  DOUT[ 14] OFF  DOUT[ 15] OFF  DOUT[ 16] OFF |
| SI[ 1] OFF Fault reset  SI[ 2] ON Remote  SI[ 3] ON Hold  SI[ 4] OFF  SI[ 5] OFF  SI[ 6] OFF Cycle start  SI[ 7] OFF  SI[ 8] ON CE/CR Select b0  SI[ 9] ON CE/CR Select b1  SI[ 10] OFF  SI[ 11] OFF  SI[ 12] OFF  SI[ 13] OFF  SI[ 14] OFF  SI[ 15] OFF  SI[ 16] ON | SO[ 1] OFF Cycle start  SO[ 2] OFF Hold  SO[ 3] OFF Fault LED  SO[ 4] OFF Batt alarm  SO[ 5] OFF  SO[ 6] OFF  SO[ 7] ON TP enabled  SO[ 8] OFF  SO[ 9] OFF  SO[ 10] OFF  SO[ 11] OFF  SO[ 12] OFF  SO[ 13] OFF  SO[ 14] OFF  SO[ 15] OFF |
| UI[ 1] ON \*IMSTP  UI[ 2] ON \*Hold  UI[ 3] ON \*SFSPD  UI[ 4] OFF Cycle stop  UI[ 5] OFF Fault reset  UI[ 6] OFF Start  UI[ 7] OFF Home  UI[ 8] ON Enable  UI[ 9] OFF RSR1/PNS1/STYLE1 |  |